feat(server): channel persists fast/medium/slow samples to metrics table

server/lib/server_web/channels/host_channel.ex

@@ -32,20 +32,35 @@ defmodule ServerWeb.HostChannel do
   def join(_topic, _params, _socket), do: {:error, %{reason: "bad_topic"}}
 
   @impl true
-  def handle_in("metric:fast", payload, socket) do
-    Logger.info("metric:fast host=#{socket.assigns.host_name} data=#{inspect(payload["data"])}")
-    {:reply, :ok, socket}
+  def handle_in("metric:" <> kind, payload, socket) when kind in ~w(fast medium slow) do
+    with {:ok, collected_at} <- parse_collected_at(payload),
+         {:ok, data} <- parse_data(payload),
+         {:ok, _} <-
+           Server.Metrics.record_sample(socket.assigns.host_id, kind, collected_at, data) do
+      Logger.debug("stored #{kind} sample host=#{socket.assigns.host_name}")
+      {:reply, :ok, socket}
+    else
+      {:error, reason} when is_binary(reason) ->
+        Logger.warning("metric:#{kind} rejected host=#{socket.assigns.host_name} reason=#{reason}")
+        {:reply, {:error, %{reason: reason}}, socket}
+
+      {:error, %Ecto.Changeset{} = cs} ->
+        Logger.warning("metric:#{kind} changeset failed: #{inspect(cs.errors)}")
+        {:reply, {:error, %{reason: "invalid_payload"}}, socket}
+    end
   end
 
-  def handle_in("metric:medium", payload, socket) do
-    Logger.info("metric:medium host=#{socket.assigns.host_name} payload=#{inspect(payload)}")
-    {:reply, :ok, socket}
+  defp parse_collected_at(%{"collected_at" => ts}) when is_binary(ts) do
+    case DateTime.from_iso8601(ts) do
+      {:ok, dt, _} -> {:ok, dt}
+      _ -> {:error, "invalid_collected_at"}
+    end
   end
 
-  def handle_in("metric:slow", payload, socket) do
-    Logger.info("metric:slow host=#{socket.assigns.host_name} payload=#{inspect(payload)}")
-    {:reply, :ok, socket}
-  end
+  defp parse_collected_at(_), do: {:error, "missing_collected_at"}
+
+  defp parse_data(%{"data" => data}) when is_map(data), do: {:ok, data}
+  defp parse_data(_), do: {:error, "missing_data"}
 
   @impl true
   def terminate(_reason, socket) do